Computation with numbers from files

Question

I have data that consists of a file1 with two columns and a file2 with one column. I need to apply this computation

for (i = 1; i == NR)

{x = ($1-T1)/Fi; print (x-int(x))} 

where $1 is a first column of file1, T1 is a first row of first column of file 1 and Fi is row i in file2.

file1

5     2
56    3
566   2
54    2

file2

1
2
6
8

The computatiou should be

{x = ($1(file1)-5)/1; print (x-int(x))}
--> output1
{x = ($1(file1)-5)/2; print (x-int(x))}
--> output2
{x = ($1(file1)-5)/6; print (x-int(x))}
--> output3
{x = ($1(file1)-5)/8; print (x-int(x))}
--> output4

Desired result are four files with a column of 4 numbers. I mean that only $1 are number that vary during the computation and the other variable are fixed.

Answer 1

awk 'FNR == NR { F[++n] = $1; next } FNR == 1 { T1 = $1 } { for (i = 1; i <= n; ++i) { x = ($1 - T1)/F[i]; print x - int(x) >"output" FNR} }' file2 file1

This first reads the contents of file2 (the first file given on the command line, which is the one with the single column in it) and stores it in the array F.

It then reads file1 and for each of its lines computes as many numbers as there are values in the F array. For each line of file1 these computed numbers are outputted into a file with the name output followed by the corresponding line number in file1.

Results:

$ ls
file1   file2   output1 output2 output3 output4
$ cat output1
0
0
0
0
$ cat output2
0
0.5
0.5
0.375
$ cat output3
0
0.5
0.5
0.125
$ cat output4
0
0.5
0.166667
0.125
$ cat output5

---

The awk script with annotations:

FNR == NR {
    # This is the first file.
    # Read its data into F, and then continue.

    F[++n] = $1
    next
} 

# We are now only processing the second file.

FNR == 1 {
    # Save T1 from the first line of the second file.
    T1 = $1
} 

{
    # Loop through F and compute x for each.
    for (i = 1; i <= n; ++i) {
        x = ($1 - T1)/F[i]

        # Print to the file given by the current line number.
        print x - int(x) >"output" FNR
    }
}