Replace fenced block with output of command in bash

Question

I'm attempting to replace a "fenced" block of text with the output from the tree command in linux (specifically in a make file). Here's my input file:

some text...
[fencetitle]
----
.
├── file1.txt
└── test
    └── file2.txt

1 directory, 2 files
----
some more text...

And I'd like to replace the contents with output from the tree command:

some text...
[fencetitle]
----
.
├── file1.txt
├── newfile.txt
└── test
    └── file2.txt

1 directory, 3 files
----
some more text...

Using the sed command, I can't seem to match using newlines with the line [fencedtitle] and ---- to ----. I am able to replace text between [fencedtitle] and ---- with the following command, however:

sed -n '/\[fencedtitle\]/{:a;N;/----/!ba;N;s/.*\n/REPLACEMENT\n/};p' file

But I can't seem to then replace REPLACEMENT with the output from the tree command. Is sed the right approach here, or is something else more appropriate?

Answer 1

You could try something like:

sed -n "/\[fencedtitle\]/{:a;N;/----/!ba;N;s/.*\n/$(tree)\n/};p" file

But this will be problematic if the output of tree contains characters that are special for regex. If you save the output of tree to a file:

tree > my-out

Then you can read it in sed without too many problems:

sed -n '/\[fencetitle\]/{p;n;p;r my-out
:a;n;/^----$/!ba};p' file

(Yes, the r command does require a new line after it, no commands may follow it on the same line.)

The p;n;p; just prints the start of the fence, then we read the file, then we skip everything till the end of the fence.

You can end the line after the r command by splitting out the rest into a separate sed expression:

sed -ne '/\[fencetitle\]/{p;n;p;r my-out' -e ':a;n;/^----$/!ba};p' file

Answer 2

I have done by below method for above example

sed "s/file1.txt/&\n|__newfile/g" example.txt

output

some text...
[fencetitle]
----
.
├── file1.txt
|__newfile
└── test
    └── file2.txt