AWK Syntax Error When Using Pattern-Action Blocks Inside Conditionals

Question

Have written some code in an awk file. Basically the code captures lines starting with ### DK and returns the block between two blank lines. Would like the capability of either using a function or directly via pattern-action.

But I get syntax error inside the conditionals.

awk: /home/mardonius/dk-search.awk:111:     /^### DK/ {
awk: /home/mardonius/dk-search.awk:111:               ^ syntax error
awk: /home/mardonius/dk-search.awk:117:     printing {
awk: /home/mardonius/dk-search.awk:117:              ^ syntax error

Here is the file's code

## dk-search.awk


function print_dk_sections(line)
 {
   ## print_dk_sections
   ##  Print all lines starting after a line beginning with 
   ##  "### DK" up to (but not including) the second empty line.
   ##  Called for each line of input to control which lines are printed.
   
   if (line ~ /^### DK/) {
      printing = 1
      empty_count = 0
      return 0
    }
    
   if (printing) {
     print line
       if (line ~ /^$/) {
         empty_count++
         if (empty_count == 2) { printing = 0 }
       }
    }
    return 1
 }


{
  
  ## Preferred default mode due to better modularity and 
  ## maintainability using a dedicated function to process lines.
  if (mode == "fn") {
     print_dk_sections($0)
   }

  ## ------------------------------------------------------------
  ## Idiomatic and efficient but less modular than using a function.
  ## Uses pattern-action blocks directly inside the condition.
  else if (mode == "direct-pa") {
    
    /^### DK/ {
       printing = 1
       empty_count = 0
       next  # Skip printing this line
     }

    printing {
      print
      if ($0 ~ /^$/) {
         empty_count++
         if (empty_count == 2) { printing = 0 }
       }
     }
   
   }

 }

The input file would look like this

## ###############################################################
##
### DK2 ⛯ opcon-search ()

opcon-search ()
 {
   ## opcon-search DIR STRING
   ##  Recursively search for STRING in all files under a directory
   ##  DIR.  Prints the name of each file containing matches, followed
   ##  by matching lines with line numbers.

   local search_dir=$1
   local search_str=$2

 }

## ###############################################################
##
### DK2 ⛯ opcon-trisquel-install ()

opcon-trisquel-install ()
 {
   ## opcon-trisquel-install
   ##  Textual installer guide for Trisquel GNU with LVM.  Provides
   ##  practical advice and commands to help users perform a secure
   ##  and flexible installation.  References another command
   ##  opcon-trisquel-root for advanced partition resizing
   ##  instructions.

   lexicon="
1. Start the Trisquel Installer and Select LVM
    - Boot from the Trisquel Installation Media.
    - Begin the Installation Process."

 }

## ###############################################################
##
### DK3 ⛯ opcon-trisquel-root

opcon-trisquel-root ()
 {
   ## opcon-trisquel-root
   ##  Simply prints some text.

   lexicon="
1. TODO"

   printf '%s\n' "$lexicon"
 }

Answer 1

I know all the awk documentation talks about pattern-action blocks, but the documentation is all wrong and it's really condition-action blocks. Using the term "pattern" made sense in the 1970s when awk was invented to look for patterns of text in the input, but today we can do far more than that, e.g. with var > 7 { print "foo" }, it'd be a real stretch of the English language to consider var > 7 a "pattern" when it is clearly just a "condition".

So, awk is a series of condition { action } blocks where the syntax of the action blocks is very similar to C and other Algol-based languages in which to test a condition you need to wrap it in if or while or similar. In your code, then, you wouldn't do:

condition1 {
    condition2 {
        action
    }
}

you'd do:

condition1 {
    if ( condition2 ) {
        action
    }
}

In comments you're asking whether $0 ~ is required in a condition - no, a regexp comparison against $0 is the default behavior in every condition statement that just contains a literal regular expression. In all cases /foo/ is equivalent to $0 ~ /foo/.

FWIW without seeing any expected output, I'd probably start with code like:

section {
    print section, $0
    if ( !NF && (++empty_count == 2) ) {
        section = ""
        empty_count = 0
    }
}
(section == "") && /^### / {
    section = $2
}

and then in the section { ... } block you can test for DK or other section identifiers if you like, assuming all sections start with ### <identifier>, and if you wanted to use a function for something then e.g.:

function handle_section(sect, line) {
    if ( sect ~ /^DK/ ) {
        print line
    }
}

section {
    handle_section(section, $0)
    if ( !NF && (++empty_count == 2) ) {
        section = ""
        empty_count = 0
    }
}
(section == "") && /^### / {
    section = $2
}

or:

function handle_dk_section(line) {
    print line
}

section {
    if ( section ~ /^DK/ ) {
        handle_dk_section($0)
    }
    if ( !NF && (++empty_count == 2) ) {
        section = ""
        empty_count = 0
    }
}
(section == "") && /^### / {
    section = $2
}

or you could buffer all lines in the section and then handle the whole section at one time when it ends, e.g.:

function handle_dk_section(sect, buf) {
    if ( sect ~ /^DK/ ) {
        printf "%s", buf
    }
}

section {
    buf = buf $0 ORS
    if ( !NF && (++empty_count == 2) ) {
        handle_dk_section(section, buf)
        section = buf = ""
        empty_count = 0
    }
}
(section == "") && /^### / {
    section = $2
}

whether buf is scalar (buf = buf $0 ORS) or array (buf[++numLines] = $0) is of course up to you based on whatever you want to do with it, and if you want the ### DK line included in the DK section just swap the order of the section condition blocks. Other trivial tweaks may be necessary.

---

Given the OPs newly posted sample input, if they just want to print the contents of each DK block with 2 blank lines after each, then using GNU awk for multi-char RS they could do:

$ awk -v RS='(^|\n)## #+\n##\n### DK[^\n]*\n\\s*' 'NR>1{sub(/\s*$/,"\n\n"); print}' file
opcon-search ()
 {
   ## opcon-search DIR STRING
   ##  Recursively search for STRING in all files under a directory
   ##  DIR.  Prints the name of each file containing matches, followed
   ##  by matching lines with line numbers.

   local search_dir=$1
   local search_str=$2

 }


opcon-trisquel-install ()
 {
   ## opcon-trisquel-install
   ##  Textual installer guide for Trisquel GNU with LVM.  Provides
   ##  practical advice and commands to help users perform a secure
   ##  and flexible installation.  References another command
   ##  opcon-trisquel-root for advanced partition resizing
   ##  instructions.

   lexicon="
1. Start the Trisquel Installer and Select LVM
    - Boot from the Trisquel Installation Media.
    - Begin the Installation Process."

 }