Filter for arbitrary AND patterns [duplicate]

Question

Consider a command which takes arguments like this: cmd foo bar baz [arbitrary args...]. How do you build a filter of AND patterns based on those arguments?

Something like this pipeline of greps:

grep foo | grep bar | grep baz

I have a hunch I can avoid eval and also building a dynamic pipeline (out of a vague worry about Bash word expansion).

I tried reaching for AWK like this:

awk "$(printf '/%s/ && ' "$@" | awk '{ $NF=""; print }')"

1. printf builds up the pattern based on args.
2. Inner awk trims off some of the trailing &&.
3. Outer awk runs the ANDs.
4. Aside: On the edge case of 0 args, my script accidentally does the right thing—match everything—by running awk '// '.

But I feel like my approach is clunky.

Edit: Ah! I just thought of another way which only uses two AWKs and is more explicit about the edge cases:

awk "$(echo "$@" | awk '
    NF == 0 { print "//" }
    NF > 0 { for (i = 1; i <= NF; i++)
        printf("/%s/%s", $i, i==NF ? "" : " && ") }')"

Answer 1

Here's a filter like that in Perl, if I gather your idea correctly:

% cat test.txt
1 asdf
2 foo
3 foo bar
4 bar

% <test.txt perl -e 'LINE: while(<STDIN>) { for $p (@ARGV) { next LINE unless /$p/ }; print }' -- foo bar
3 foo bar

Answer 2

I think what you're probably looking for is something like this, using any POSIX awk:

$ cat cmd
#!/usr/bin/env bash

numPats=$(( $# - 1 ))
printf -v pats '%s\n' "${@:1:$numPats}"
shift "$numPats"

pats="$pats" \
awk '
    BEGIN {
        split(ENVIRON["pats"], tmp, /\n/)
        for ( i in tmp ) {
            pats[tmp[i]]
        }
    }
    {
        for ( pat in pats ) {
            # For Extended Regexp partial matching:
            if ( $0 !~ pat ) {
                next
            }
            # For Literal String partial matching uncomment this instead:
            # if ( ! index($0, pat) ) {
            #     next
            # }
        }
        print
    }
' "$1"

but without sample input and expected output that's just an untested guess. The above assumes the last argument passed to cmd will be the file name you want it to search in for the preceding arguments.