I hope the title explains this correctly. I am currently trying to print out an array after counting unique values from a spreadsheet.
My awk command works correctly:
awk -F"," 'NR>1{col[$1,$9]++} END {for (i in col) printf("%s: %d\n", i, col[i])}' my_file.csv | sort
When printing though I get a special character that looks like a question mark.
How do I print this with a comma + space between the year and the season.
eg: 1896, summer: 151
Awk is treating [$1,$9] as a pseudo multi-dimensional array, and inserting its internal SUBSEP character. This is documented in The GNU Awk User's Guide for example:
SUBSEP
The subscript separator. It has the default value of "\034" and is used to separate the parts of the indices of a multidimensional array. Thus, the expression ‘foo["A", "B"]’ really accesses foo["A\034B"] (see section Multidimensional Arrays).
Ex.
$ echo 'A,A' | gawk -F, '{col[$1,$2]++} END{for(i in col) print i}' | od -to1
0000000 101 034 101 012
0000004
If you want a 1d array indexed by the literal value of the string, you can use [$1 "," $9] or more generally [$1 FS $9] (the latter ensures that the solution will work for data with other separators):
$ echo 'A,A' | gawk -F, '{col[$1 FS $2]++} END{for(i in col) print i}'
A,A
If you want comma+space either use [$1 FS" " $2] or set SUBSEP = FS" " in a BEGIN block.
$0 as a single index rather than changing SUBSEP. To make the examples more relevant, consider reading input that is not comma-delimited.
echo 'A,A' was just intended as a MWE (since the OP didn't provide one). IMHO using $0 in this context would not be helpful, since the question is clearly about composing an index from separate fields.
$0 as an index to get the same effect as you get, but without having to use FS in the index expression. You could also argue that the question is not about composing an index but to extract the individual parts of the index. It just happens that the user wants all the parts with commas between them.
When you use an index like $1,$9 into an array in awk, the index that actually gets used is $1 SUBSEP $9, where SUBSEP is a character that is unlikely to occur in actual data (the actual value is implementation-defined, but octal 34, a character called "file separator", is commonly used). This is due to standard awk only having one-dimensional arrays. Multi-dimensional arrays are "simulated" by concatenating the indexes with this SUBSEP value as delimiter.
GNU awk has real multi-dimensional arrays, but the syntax is [i][j] rather than [i,j].
You may get the original bits of the index returned to you if you split the index on this SUBSEP value:
for (i in col) {
split(i, k, SUBSEP)
year = k[1]
season = k[2]
printf "%s, %s: %s\n", year, season, col[i]
}
or just
for (i in col) {
split(i, k, SUBSEP)
printf "%s, %s: %s\n", k[1], k[2], col[i]
}
Both fragments above assumes that you know that your index i always contains two parts.
