Really exit Awk script

Question

Perl and Ruby exit actually exits:

$ perl -e 'BEGIN {print 1; exit}; END {print 2}'
1

$ ruby -e 'BEGIN {print 1; exit}; END {print 2}'
1

Not so for Awk:

$ awk 'BEGIN {print 1; exit}; END {print 2}'
1
2

I tried to solve this with a "help.awk"

function really_exit() {
  IM_SURE = 1
  exit
}
END {
  if (IM_SURE) {
    exit
  }
}

but this creates its own problem. If "prog.awk" has only the begin block:

BEGIN {
  print "start"
}

Then running it:

awk -f help.awk -f prog.awk

will cause it to hang waiting for input. Is a better solution available, for really exiting an Awk script?

Can ever the same BEGIN block be usefully used for both applications with and without input? If not, why not call exit from the BEGIN block? — Hauke Laging
– Hauke Laging, Commented Mar 30, 2018 at 23:21
Instead of using exit you can call system() and kill the awk process directly. — Hauke Laging
– Hauke Laging, Commented Mar 30, 2018 at 23:27
The END blocks are probably executed in the order in which they appear. So if your BEGIN block calls exit and the first END block (in your helper script) calls exit again then the "real" END blocks should not get executed. — Hauke Laging
– Hauke Laging, Commented Mar 30, 2018 at 23:32
seems a bug? awk(1) on my system says exit should "exit immediately" and nothing about going on to END blocks — thrig
– thrig, Commented Mar 30, 2018 at 23:54
The fact that END executes even after explicit exit is documented: gnu.org/software/gawk/manual/html_node/Exit-Statement.html — glenn jackman
– glenn jackman, Commented Mar 31, 2018 at 4:56

Zombo · Accepted Answer · 2018-04-03 01:48:47Z

If an Awk program has a "middle" or END block, then input is read. We can counter this by providing null input:

$ cat prog.awk
1
END {
  print "fin"
}

$ awk -f prog.awk /dev/null
fin

If we want this to be the default, we can add a block to "help.awk":

BEGIN {
  if (ARGC == 1 && !system("[ -t 0 ]")) {
    ARGV[ARGC++] = "/dev/null"
  }
}

However this creates an important change; Awk will not read from terminal unless you add a dash:

awk -f help.awk -f prog.awk -

or modify "prog.awk":

getline < "-"

Example reading input:

$ cat prog.awk
/4/ {
  really_exit()
}
1
END {
  print "fin"
}

$ seq 10 | awk -f help.awk -f prog.awk
1
2
3

Example not reading input:

$ cat prog.awk
BEGIN {
  print "start"
  really_exit()
}
END {
  print "fin"
}

$ awk -f help.awk -f prog.awk
start

1 Answer 1