Extract email addresses from line, with multiple email addresses per line

Question

I have a text file that mixes names and email addresses, in a comma-separated list.

First Person <[email protected]>, Second Person <[email protected]>, Third <[email protected]>
Fourth Person Long Name <[email protected]>
Fifth <[email protected]>, Sixth Person <[email protected]>

I want to extract a comma-separated list of email addresses for each line:

[email protected], [email protected], [email protected]
[email protected]
[email protected], [email protected]

I tried using grep -o but it printed each email address on a separate line. I want to keep the same number of lines that was in the original file. I'm open to any available regex tool (awk, sed, grep, etc).

Answer 1

With perl, to extract the parts inside <...>:

$ perl -lne 'print join ", ", @emails if @emails = /<(.*?)>/g' <your-file
[email protected], [email protected], [email protected]
[email protected]
fifth.example.com, sixth.example.com

That's skipping the lines that don't have any emails. If you want to have empty lines of output instead for those, that's even simpler:

perl -lpe '$_ = join ", ", /<(.*?)>/g' <your-file

Answer 2

Email addresses are bracketed with <...> so it's easy to pick them out. Remove the leading part that isn't an email address upto the first <; remove the trailing part from the last >; replace the middle parts >...< with a comma & space

sed -e 's/^[^<]*<//' -e 's/>[^<]*$//' -e 's/>[^<]*</, /g' file

[email protected], [email protected], [email protected]
[email protected]
fifth.example.com, sixth.example.com

This will not handle pathological addresses that, for example, contain angle brackets themselves. (I'd call these valid but stupid.) See other answers for more robust but consequently more complex solutions

Answer 3

Using gawk:

$ awk -vFPAT='<.[^>]*>' -vOFS=',' 
             '{
             $1=$1; # force record to be reconstituted
             gsub(/[<>]/,"") # gsub(/pattern to be removed/, "")
     }1' file

FS describes the data beteen fields (“what fields are not”) and FPAT describes the fields themselves (“what fields are”). This leads to a subtle difference in how fields are found when using regexps as the value for FS or FPAT.¹

About $1=$1:

Here FPAT sets fields andOutput Field Separator is set but the full record $0 is still old. To reconstruct the $0 using the current values of all fields and OFS, $1 is assigned to itself.

But this does not work, because nothing was done to change the record itself. Instead, you must force the record to be rebuilt, typically with a statement such as ‘$1 = $1’.²

---

^{¹See FS versus FPAT.}

^{²See for Understanding $0.}

Answer 4

perl -F',' -lane '@F = map {  s/^.*<(.*?)>.*/$1/r } @F;
   print join(", ", @F)' input.txt 
[email protected], [email protected], [email protected]
[email protected]
fifth.example.com, sixth.example.com

This auto-splits the input on commas and stores it in array @F. Then it use map() to run a regex over each element of @F to remove everything outside of angle-brackets < and >

It just assumes that everything inside angle brackets is a valid email address. Much of the time this is a reasonable assumption because that's how email addresses are supposed to be bounded.

This is not always true with real world email addresses and a better version would use Regexp::Common::Email::Address to validate each email address before accepting and printing it.

---

Here's a better version, written as a standalone script rather than a one-liner because it's easier to read and understand that way:

#!/usr/bin/perl

use strict;
use feature 'say';

use Regexp::Common qw(Email::Address);

while(<<>>) {
  next if m/^\s*$/;            # ignore empty lines
  chomp;                       # strip trailing \n

  my @addr = ();               # reset @addr array for each input line

  foreach (split /\s*,\s*/) {  # split on commas with optional whitespace
    next unless m/\@/;         # ignore elements without an @
    s/^.*<(.*?\@.*?)>.*/$1/;   # strip everything not inside < >

    # Add to @addr array if it's a valid address
    push @addr, $_ if  m/$RE{Email}{Address}/;
  };

  # print the addresses found on the current line, if any.
  say join(", ", @addr) if @addr;
};

Save that as, e.g., extract-addresses.pl and make it executable with chmod +x extract-addresses.pl. Then run it as extract-addresses.pl filename or pipe your data into it (it works with either or both).

For example, with an input file (input.txt) that contains this:

First Person <[email protected]>, Second Person <[email protected]>, Third <[email protected]>
Fourth Person Long Name <[email protected]>
Fifth <fifth.example.com>, Sixth Person <sixth.example.com>
bad<user> <[email protected]>, another<<<bad<<<user>>> xyz
<"<ohdear>first"@example.com>, Last, First <[email protected]>

It produces this output:

$ ./extract-addresses.pl input.txt 
[email protected], [email protected], [email protected]
[email protected]
[email protected]
[email protected]

Technically, another<<<bad<<<user>>> xyz is a valid email address even though it doesn't have an @ or a FQDN (Fully Qualified Domain Name, i.e. a hostname or domain name). It could be OK as an alias or in a virtual domain, but is probably not a valid user account name but even that is possible, depending on the kind of server. Anyway, this script is written to ignore addresses without an @ symbol in them.

And, as @StephenKitt points out, <"<ohdear>first"@example.com> is also a valid email address. This script does not handle pathological cases like that - as a judgemental programmer, I have arbitrarily decided that whoever owns that address does not deserve to receive email :-) and more importantly, as the great copout says, handling addresses like that is "left as an exercise for the reader". It probably wouldn't be too hard, but I haven't even finished my first coffee of the day yet.

Answer 5

Using any awk, assuming the input is as simple/regular as in the provided example:

$ awk -F'[<>]' -v OFS=', ' '{for (i=2; i<=NF; i+=2) printf "%s%s", $i, (i<(NF-1) ? OFS : ORS)}' file
[email protected], [email protected], [email protected]
[email protected]
[email protected], [email protected]