zsh: check exit code of pipeline of commands

Question

I have long pipeline of commands in zsh script:

pv /dev/sda > sda.raw | sha256sum > sda.raw.sha256 | cut -c61-64 | read SHASUM

how can I check inside an if statement, that all commands exited successfully?

I know about ${pipestatus[@]}, but it is an array. So I would have to check each element individually.

Is there some shortcut to check that ${pipestatus[@]} contains only 0 ?

UPDATE:

I have discovered some weird behavior:

for testing, I set up small filesystem (10MB) so that it fills up quickly:

#!/bin/zsh

set -o pipefail

if pv /dev/zero > loop/file ; then
echo OK
else
echo FAIL
fi

as expected, I get following error, and "FAIL" printed:

pv: write failed: No space left on device

However, when I change the pv command just slightly, it suddenly does not print any error, and the pv command seems to run indefinitely (even though there is no space left on the device)

#!/bin/zsh

set -o pipefail

if pv /dev/zero > loop/file | sha256sum ; then
echo OK
else
echo FAIL
fi

Answer 1

Two options:

1. set the pipefail option from ksh (set -o pipefail), then the exit status of a pipeline will be that of the right-most pipeline component that failed.

   set -o pipefail
   if ! A | B | C; then
     echo at least one of the commands failed.
   fi
   

2. look for non-zero values in $pipestatus. With the extendedglob option enabled, $pipestatus[(r)^0] (or $pipestatus[(r)<1->] which doesn't require extendedglob) will return the exit status of the left-most failing pipeline component and $pipestatus[(R)^0] of the right-most, so you can do:

   set -o extendedglob
   A | B | C
   if (( $pipestatus[(r)^0] )); then
     echo at least one of the commands failed.
   fi
   

   or

   A | B | C
   if (( $pipestatus[(r)<1->] )); then
     echo at least one of the commands failed.
   fi
   

   With the I subscript flag instead of r/R, you'll get the Index of the right-most matching element, so you can do:

   A | B | C
   if (( failed = $pipestatus[(I)<1->] )); then
     echo component $failed failed.
   fi
   

   ${pipestatus:#0} will expand to the components of $pipestatus except 0, so you could also do:

   A | B | C
   failed_statuses=( ${pipestatus:#0} )
   if (( $#failed_statuses )); then
     echo "${#failed_statuses} command(s) failed. Statuses: $failed_statuses"
   fi