How to delete all text before and when string occurs on sed

Question

I remembered how to do this and even learned it from Stack Exchange, but forgot how I googled it so now I can't find it. The answers I am finding now are not what I'm looking for. Here is an example text:

The quick
brown fox
jumps over
the lazy
dog

I want sed to remove everything before and when it says "jum" so the output would be something like this:

ps over
the lazy
dog

How do I do this?

Answer 1

sed -ne '1,/^jum/{s/^jum//p;d;}' -e p

As @Sundeep states in comment, if you have GNU sed, use preferably sed -ne '0,/^jum/{s/^jum//p;d;}' -e p. This would work even if jum on the first line. which is not the case with 1,/^jum/.

Here is what it does:

• sed -n: don't print anything unless told to
• 1,/^jum/: for lines between the 1st one and the one that starts with jum inclusive:
  • s/^jum//p: if you can remove "jum" at start of line, print the result
  • d: and proceed with next line
• -e p: all other lines, just print them.

Answer 2

Using GNU sed, and assuming your file is small enough to fit in memory, you can do this:

$ sed -z 's/.*jum//' file 
ps over
the lazy
dog

The -z tells sed to treat its input as NUL-separated, meaning that it expects a NUL (\0) to signidfy the end of each line. Since your file will have no NUL characters, this has the effect of sed treating the entire file as a single line so we can do the whole thing in a single s/// operation.

Note that this will find the last jum in the file and delete everything before that. If there are other occurrences of jum earlier, those will be removed.

Answer 3

With awk:

$ awk 'sub(/^jum/, ""){f=1} f' ip.txt
ps over
the lazy
dog

If the substitution succeeds, set a flag to print the lines.