0

It seems to be a bit strange that the logical operator of && cannot work within the awk if regex pattern, which versus the logical operator of || could work fine！
Note: but the logical operator of && can do work within the pure simple awk regex pattern, so why ?

# 
# 
# cat /etc/passwd|awk '$0 ~/[Ss]ystem/ || /puls/ {print $0}'
dbus:x:81:81:System message bus:/:/sbin/nologin
pulse:x:497:495:PulseAudio System Daemon:/var/run/pulse:/sbin/nologin
# 
# 
# 
# cat /etc/passwd|awk '$0 ~/[Ss]ystem/ &&  /puls/ {print $0}'
pulse:x:497:495:PulseAudio System Daemon:/var/run/pulse:/sbin/nologin
# 
# 
# 
# cat /etc/passwd|awk '$0 ~/[Ss]ystem|puls/ {print $0}'
dbus:x:81:81:System message bus:/:/sbin/nologin
pulse:x:497:495:PulseAudio System Daemon:/var/run/pulse:/sbin/nologin
# 
# 
# 
# cat /etc/passwd|awk '{k1[NR]=$0}END{for(i=1;i<=NR;i++)if(k1[i] ~/[Ss]ystem/ || /puls/){print k1[i]}}'
dbus:x:81:81:System message bus:/:/sbin/nologin
pulse:x:497:495:PulseAudio System Daemon:/var/run/pulse:/sbin/nologin
# 
# 
# cat /etc/passwd|awk '{k1[NR]=$0}END{for(i=1;i<=NR;i++)if(k1[i] ~/[Ss]ystem/ && /puls/){print k1[i]}}'
# 
# 
# cat /etc/passwd|awk '{k1[NR]=$0}END{for(i=1;i<=NR;i++)if(k1[i] ~/[Ss]ystem/ && /puls/){print k1[i]}}'
# 
# 
# cat /etc/passwd|awk '$0 ~/[Ss]ystem/ &&  /puls/ {print $0}'
pulse:x:497:495:PulseAudio System Daemon:/var/run/pulse:/sbin/nologin
# 
#


Now the newest situation might become much more strange than before after I did few modifications!
Why the below same regex pattern with both the array variable and logical operator && can work ?
Note: this should explain that the problem of && within some if regex pattern has nothing to do with the array variable itself at least. 
# 
# 
# cat /etc/passwd|awk '{k0[NR]=$0;if(k0[NR] ~/[Ss]ystem/ && /puls/){print k0[NR]}}'
pulse:x:497:495:PulseAudio System Daemon:/var/run/pulse:/sbin/nologin
# 
# 
# cat /etc/passwd|awk '{k0[NR]=$0;if(k0[NR] ~/[Ss]ystem/ || /puls/){print k0[NR]}}'
dbus:x:81:81:System message bus:/:/sbin/nologin
pulse:x:497:495:PulseAudio System Daemon:/var/run/pulse:/sbin/nologin
# 
# 
# cat /etc/passwd|awk '{k0[NR]=$0;if(k0[NR] ~/[Ss]ystem/ && /puls/){print k0[NR]}}'
pulse:x:497:495:PulseAudio System Daemon:/var/run/pulse:/sbin/nologin
# 
#
Improve this question
12
  • 1
    Your question shows multiple scripts and their actual output, but it doesn't show the input file nor the expected output for each script so it's hard to tell what it is about each of your scripts you think isn't working - we can't tell what you expected to happen from a script that doesn't do whatever it is you expected. Please edit your question to provide sample input and the expected output for whatever script(s) you think aren't behaving as expected. Commented Dec 5, 2022 at 14:17
  • 1
    FYI, cat file | awk '…' can be more succinctly written as awk '…' file Commented Dec 5, 2022 at 16:56
  • 2
    The "new situation" is that you already have an explanation for the results you originally got, but you have now added new errors, and still not fixed the previous issues. You carefully store every input line in an array for future access, but you have now removed all END block processing so the stored results are never accessed. Of your new results, the first and third are identical, and all the outcomes are correct. What else did you expect to happen? Commented Dec 7, 2022 at 15:44
  • 1
    There is no "special problem". You simply do not understand the difference between the boolean operators && and ||. Commented Dec 7, 2022 at 15:54
  • 1
    You keep throwing up scripts that produce output that looks reasonable but you think are misbehaving somehow yet you won't show us the sample input nor tell us what output you expected to get instead. Despite that you got answers to the question you asked and now you've thrown up more scripts in the same vein as your original (but may or may not contain some different question, I can't tell) and say they're somehow different but again don't provide input or expected output. Please read the answers you got to your original question and adjust your scripts per their recommendations. Commented Dec 7, 2022 at 16:09

3 Answers 3

Reset to default
3

in first part

$0 ~/[Ss]ystem/ &&  /puls/

is implicit for

$0 ~/[Ss]ystem/ && $0 ~ /puls/

so

if(k1[i] ~/[Ss]ystem/ && /puls/)

should be written as

if(k1[i] ~/[Ss]ystem/ && k1[i] ~ /puls/)
  • in former case /pusl/ is likely to be (*) matched against last line of /etc/passwd.
  • also see man awk but ~ (and !~) have priority over &&

(*) confirmed, if I move PulseAudio line to last line, as match is made.

Improve this answer
3

You are assuming the wrong association of operators, and possibly their meaning. Numbering your tests cases:

  1. $0 ~/[Ss]ystem/ checks if "$0 matches /RE/". The || /puls/ condition is not even tested: it is "short-circuited" because the overall condition is already known to be true.

  2. The && checks if both conditions are true, and matches only one line.

  3. The combined RE (two alternative cases with |) matches two lines.

  4. This matches both the stored lines that contain System.

  5. This matches nothing. It tests a stored line from the array, but the '/puls/' tests the value in $0 after you have run off the end of the file -- it does not refer to k1[i]. $0 would still contain the last line of the file, and I conjecture that the complete input file has no such line at the end. The && requires both conditions to be true, so no line matches.

  6. Is a duplicate of (5).

  7. is a duplicate of (2).

Improve this answer
1
  • Could you please tell me how about the newest situation ? Almost with the same if regex pattern using the array and logical operator && Commented Dec 7, 2022 at 12:45
2

This is a deconstruction of your "newest situation" addition to your initial question, to simplify matters.

cat /etc/passwd|awk '{k0[NR]=$0;if(k0[NR] ~/[Ss]ystem/ && /puls/){print k0[NR]}}'

The cat adds nothing to the code, because awk can read files itself. (Google UUOC for more.)

Storing the input line in an array, and then testing the value in the same statement, adds nothing (as there is no END block). So we can simplify to:

awk '{if($0 ~/[Ss]ystem/ && /puls/){print $0}}' /etc/passwd

Using a ~ pattern match is identical to a plain RE, so simplify to:

awk '{if(/[Ss]ystem/ && /puls/){print $0}}' /etc/passwd

Using an if is identical to a pattern outside the braces, so:

awk '/[Ss]ystem/ && /puls/ {print $0}' /etc/passwd

print $0 is identical to print, and { print } as an action is the default, so:

awk '/[Ss]ystem/ && /puls/' /etc/passwd

Your initial assertion that && cannot work, and || works fine, is false.

This reads as "if both pattern A and pattern B are present in this input line":

awk '/[Ss]ystem/ && /puls/' /etc/passwd

This reads as "if either pattern A or pattern B is present in this input line":

awk '/[Ss]ystem/ || /puls/' /etc/passwd
Improve this answer
1
  • I can feel that your explanation is so pertinent and brilliant. You are right. Commented Dec 8, 2022 at 12:30

You must log in to answer this question.

Start asking to get answers

Find the answer to your question by asking.

Ask question

Explore related questions

See similar questions with these tags.