4 
cat A.tsv
1,a,d
2,b,e
3,c,f

$ awk -F ',' -v OFS="," '{print $2, $3}' A.tsv 
a,d
b,e
c,f
  • I expected the following 4 commands to give the same results as above:
$ awk 'FS=","; OFS=","; {print $2, $3}' A.tsv 
1,a,d
1,a,d
,
2,b,e
2,b,e
b,e
3,c,f
3,c,f
c,f

$ awk -F ',' 'OFS=","; {print $2, $3}' A.tsv 
1,a,d
a,d
2,b,e
b,e
3,c,f
c,f

$ awk -v OFS="," 'FS=","; {print $2, $3}' A.tsv 
1,a,d
,
2,b,e
b,e
3,c,f
c,f

$ awk -F ',' 'FS=OFS; {print $2, $3}' A.tsv 
1,a,d
a d
2,b,e
 
3,c,f

Can someone explain why the last 4 commands have different results than the first?

Refer: Difference between awk -FS and awk -f in shell scripting - Stack Overflow

Improve this question

1 Answer 1

Reset to default
18

Awk programs consist of pattern {action} pairs, where {action} is performed if pattern evaluates TRUE. If pattern is omitted, it is assumed TRUE by default, while if {action} is omitted, the default action is {print}.

In

awk 'FS=","; OFS=","; {print $2, $3}' A.tsv

you have:

  1. pattern FS="," which assigns , as the value of FS, and as a side effect evaluates TRUE, triggering the default action {print}

  2. pattern OFS="," likewise assigns , to OFS, evaluates TRUE and triggers the default {print} action a second time

  3. action {print $2,$3} with no pattern, so the default TRUE is assumed and the action is triggered. However FS was not set to , until the first record had already been processed, so $2 and $3 are both empty (since awk used the default whitespace FS to parse the first record, assigning the whole record to $1). On subsequent records, it prints the expected comma-delimited values.

You probably intended to assign FS="," and OFS="," in an action before record processing begins - that's the function of a BEGIN block:

awk 'BEGIN{FS=","; OFS=","} {print $2, $3}' A.tsv

or

awk -F ',' 'BEGIN{OFS=FS} {print $2, $3}' A.tsv

Alternatively, you can pass variable assignments as arguments before the filename argument(s) (this is sometimes useful if you are processing multiple files and want to set different field separators for each)

awk '{print $2, $3}' FS="," OFS="," A.tsv
Improve this answer
6
  • Is it equivalent to awk -F ',' -v OFS="," '{print $2, $3}' A.tsv Commented Jul 26, 2021 at 2:04
  • Or awk 'BEGIN{FS=OFS=","} ... '. Commented Jul 26, 2021 at 8:05
  • 4
    I know all the AWK documentation says "pattern" but it's all wrong. Awk is made up of <condition> { <action> } statements, not <pattern> { <action> } statements. The latter made some sense in the very first awk version which really only did pattern matching but is woefully misleading and outdated for any awk version since the 1980s. In what way is foo == 17 a pattern? It's not, it's a condition. In what way is TRUE a pattern? It's not, it's a condition. When we write if (X) <action> in C, we don't say X is a pattern, it's a condition. And so on... Commented Jul 26, 2021 at 21:50
  • 1
    @Porcupine no, awk '{print $2, $3}' FS="," OFS="," A.tsv is similar to awk -F ',' -v OFS="," '{print $2, $3}' A.tsv but it's not equivalent. They are different in when the assignments take effect (in BEGIN for -v, after it for arg list), and whether or not escape sequences get translated (they do for -v, they don't for arg list) and whether or not they are stored in ARGV and impact ARGC (they do not for -v, they do for arg list). Commented Jul 26, 2021 at 21:58
  • 1
    Some people refer to the whole <condition> { <action> } statement as a "rule" (we just saw such a reference on the bug-gawk mailing list IIRC), but for me "rule", like "pattern", is kinda vague and needs to be defined in any given context. You can't go wrong with saying <condition> { <action> } - that is 100% accurate and unambiguous. Commented Jul 26, 2021 at 22:01

You must log in to answer this question.

Start asking to get answers

Find the answer to your question by asking.

Ask question

Explore related questions

See similar questions with these tags.