Awk regex for matching a set of values

Question

I having an Issue with awk regex matching. I was trying to match a particular column with a regex pattern (\"\.\"|0|1). This column can have only values ".",0 or 1. But my regex pattern is not matching in awk while the data in column is ".". any thoughts??

code

awk -F "$delimitter" -v n="$column" -v m="$pattern" 'NR!=1 && $n !~ "^" m "$" {
                         printf "%s:%s:%s\n", FILENAME, FNR, $n  > "/dev/stderr"
                         count++
                       }
                       END {print count+0}' input.txt 2>> errors.log

While you seem to have gotten the answer you needed, could you for the benefit of future readers edit your post to include example input, desired output and the unwanted current output of your awk program? — AdminBee
– AdminBee, Commented Jul 1, 2021 at 14:00

αғsнιη · Accepted Answer · 2021-07-01 14:04:32Z

If you want the pattern to match exactly on either "." (with quotes included), 0 or 1, you'd need the pattern to be ^("\."|[01])$ or ^("[.]"|[01])$ or ^("\."|0|1)$, etc.

But when using -v to pass that pattern to awk, you have the problem that awk treats \ specially there (same happens for -F x which is similar to -v FS=x), so you'd need to escape the backslashes here.

It's better to use ENVIRON to pass arbitrary strings from shell to awk as that doesn't have that issue.

So:

pattern='"\."|0|1'
PATTERN=$pattern DELIMITER=$delimiter awk -v n="$n" '
  BEGIN {FS = ENVIRON["DELIMITER"]; m = ENVIRON["PATTERN"]}
  $n ~ "^(" m ")$" {...}'

(still using -v for n as those are expected to be numbers so without backslash).

Note the (, ) above. ^x|y$ would be either x at the start or y at the end.

Ed Morton · Accepted Answer · 2021-07-01 14:30:53Z

Don't use the word "pattern" when matching text as it's highly ambiguous. Use "string" or "regexp", whichever one you mean. See how-do-i-find-the-text-that-matches-a-pattern for more information.

It sound like you're going about this wrong and using a regexp comparison where a string comparison in a hash lookup would be clearer, less fragile and more efficient.

valid='"."|0|1'
awk -F "$delimitter" -v n="$column" -v m="$valid" '
    BEGIN {
        split(m,tmp,"|")
        for (i in tmp) {
            valid[tmp[i]]
        }
    }
    NR>1 && !($n in valid) {
        printf "%s:%s:%s\n", FILENAME, FNR, $n  > "/dev/stderr"
        count++
    }
    END {print count+0}
' input.txt

If any of the shell variables can contain escape sequences (those in your example do not) then see https://stackoverflow.com/questions/19075671/how-do-i-use-shell-variables-in-an-awk-script for other ways than -v to pass their values to awk, e.g. ENVIRON[] or ARGV[].

cas · Accepted Answer · 2021-07-01 05:05:00Z

0

Try [.01] as your pattern.

That's a bracket expression which matches only ., 0, and 1.

NOTE: outside of a bracket expression, you'd have to escape a . as \. (otherwise it will match ANY character), but inside a bracket expression it will be treated as a literal .

answered Jul 1, 2021 at 5:05

cas

84.3k9 gold badges136 silver badges205 bronze badges

1

OP seems wants ".",0 or 1 to match

αғsнιη
– αғsнιη

2021-07-01 14:06:26 +00:00
Commented Jul 1, 2021 at 14:06

Add a comment |

Stack Exchange Network

Awk regex for matching a set of values

3 Answers 3

You must log in to answer this question.

Hot Network Questions

Awk regex for matching a set of values

3 Answers 3

You must log in to answer this question.

Related

Hot Network Questions