This can be done in awk, but IMO is much easier to do in perl. And that's even before you consider that there are over 800 perl library modules for various natural language processing tasks in Lingua::*, which is what you seem to be doing.
The following perl script first builds up a commonly used perl data structure called a Hash-of-Arrays (HoA) using the filenames as the keys to the an associative array (aka hash), and each key's values being an indexed array of names. See man perldsc for more info on HoA and other perl data structures.
The %files HoA would end up with data like:
{
"65482.txt" => ["Ito"],
"73586.txt" => ["David Juno Ilrcwrry Hold", "David Jones", "Jacob FleUchbautr"],
}
It also uses an array called @order to remember the order in which each filename was seen, so that they can be processed later in the same order (this is often useful because perl hashes, as in many other languages, are inherently unordered. If you don't care about the order, you can just iterate over the keys of the hash instead)
If a filename does not exist, it prints a warning message to STDERR and skips to the next line of the "first" file. The print STDERR ... line can be deleted or commented out if you don't want the warnings, or just redirect stderr to /dev/null when you run it.
Once it has finished building the %files HoA, it opens each file for read, creates and pre-compiles a regular expression matching any of the names wanted for that particular file, and prints every line matching the RE.
The regular expressions it builds would end up with values like:
(((\w+\s+){2})(David Juno Ilrcwrry Hold|David Jones|Jacob FleUchbautr)((\s+\w+){2}))
The reason for doing it this way is so that each filename only has to be processed once, and each line of each file only has to be examined once to see if it matches one of the names. If you have many files and/or if they are very large, this results in an enormous performance boost over the naive approach of reading and matching every line of every file repeatedly, once for every name listed in the "first" file - e.g. if you had 1000 files with 1000 lines each, and a total of 50 names to match, the naive method would have to read and match a line 50 million times (files * lines * names) instead of just 1 million times (files * lines)
The script is set up to make it easy to choose how to match the words before and after a matched name. Un-comment only one of the two my $count= lines in the script. The first strictly requires exactly two words before AND after each name - this is already un-commented. The second is relaxed about how many words can exist before or after a name (from 0 to 2).
#!/usr/bin/perl -l
use strict;
my %files = ();
my @order = ();
# Un-comment only one of the following two lines.
my $count=2;
#my $count='0,2';
# First, build up a HoA where the key is the filename and
# the value is an array of names to match in that file.
while(<>) {
s/^\s+|\s+$//; # strip leading and trailing spaces
next if (m/^$/); # skip empty lines
my ($name,$filename) = m/^(.*)\s+(.*)$/; # extract name and filename
# warn about and skip filenames that don't exist
if (! -e $filename) {
print STDERR "Error found on $ARGV, line $.: '$filename' does not exist.";
next;
};
# remember the order we first see each filename.
push @order, $filename unless ( defined($files{$filename}) );
# Add the name to the %files HoA
push @{ $files{$filename} }, $name;
};
# Process each file once only, in order.
foreach my $filename (@order) {
open(my $fh,"<",$filename) || die "Error opening $filename for read: $!\n";
my $re = "(((\\w+\\s+){$count})(" . # two words
join('|',@{ $files{$filename} }) . # the names
")((\\s+\\w+){$count}))"; # and two words again
$re = qr/$re/; # add an 'i' after '/' for case-insensitive
while(<$fh>) {
if (m/$re/) {
my $found = join(" ",$4,$2,$5);
$found =~ s/\s\s+/ /g;
print $found
};
};
}
Save as, e.g. match.pl and make executable with chmod +x match.pl, and run like:
$ ./match.pl first.txt
Error found on first.txt line 2: '73586.txt' does not exist.
Error found on first.txt line 3: '73586.txt' does not exist.
Error found on first.txt line 4: '73586.txt' does not exist.
Ito path of etmlmbimiiit tlmmgli
BTW, it's not what you asked for, but I'd recommend printing the matching name separated from the found words with a colon (:) or anything other than a space. A tab is good too. This will make it much easier to parse the output file with other programs. i.e.
Ito:path of etmlmbimiiit tlmmgli
You can do this by changing the my $found = line to:
my $found = "$4:" . join(" ",$2,$5);
or
my $found = "$4\t" . join(" ",$2,$5);
$i~nmrather than$i~$nm