Print content between first matching brackets

Question

Input example:

START{
    some text

    {
      more text}
almost there
}
nothing important{
...

Desired output:

START{
    some text

    {
      more text}
almost there
}

First open bracket could be in different positions:

START{...
START {...
START
{...

Start could also contain special characters such as: *

I want to print out everything including from START and everything between first matching {} (in bash). I was thinking about having a counter that increments when it finds { and decrements when it finds }. When the result is zero it stops printing out (curly brackets are always matching).

Answer 1

A simple brute force approach that'll work in any awk in any shell on all Unix boxes:

$ cat tst.awk
s=index($0,"START") { $0=substr($0,s); f=1 }
f { rec = rec $0 RS }
END {
    len = length(rec)
    for (i=1; i<=len; i++) {
        char = substr(rec,i,1)
        if ( char == "{" ) {
            ++cnt
        }
        else if ( char == "}" ) {
            if ( --cnt == 0 ) {
                print substr(rec,1,i)
                exit
            }
        }
    }
}

$ awk -f tst.awk file
START{
    some text

    {
      more text}
almost there
}

Answer 2

With pcregrep:

start_word='START'
pcregrep -Mo "(?s)\Q$start_word\E\h*(\{(?:[^{}]++|(?1))*+\})" < your-file

With zsh builtins:

set -o rematchpcre
start_word='START'
[[ $(<your-file) =~ "(?s)\Q$start_word\E\h*(\{(?:[^{}]++|(?1))*+\})" ]] &&
  print -r -- $MATCH

Those use PCRE's recursive regexp feature, where (?1) above recalls the regexp in the first (...) pair.

If you have neither pcregrep nor zsh, you can always resort to the real thing (perl, the P in PCRE):

perl -l -0777 -sne '
    print $& if /\Q$start_word\E\h*(\{(?:[^{}]++|(?1))*+\})/s
  ' -- -start_word='START' < your-file

(note that all but the perl one assume the $start_word doesn't contain \E).