How this code can get shorter?

With zsh:

#! /bin/zsh -
cd /home/peace || exit
set -o extendedglob # for (#i)
pdf=(*.(#i)pdf(.ND)) # all pdf files case insensitive, including hidden ones
                     # in the current directory, only considering regular files.
colors=(yello green blue grey black white)

(($#pdf)) || exit 0 # exit with success if there's no pdf file (job already done)

ret=0
for color ($colors) {
  files=(${(0)"$(pdfgrep -ilZe $color -- $pdf)"}) # all files containing the color
                                                  # using NUL-delimited records
  if (($#files)) { # some files were found
    mv -i -- $files Desktop/$color/ || ret=$? # move them, record failures
    pdf=(${pdf:|files}) # remove the files from the list as we've moved them
  }
}
exit $ret

That minimizes the number of invocations of pdfgrep and the number of times the /home/peace directory is being read.

I can see some space for improvements.

• first parameter for find is directory, not path with "*" at the end;

• find does search inside sub-directories, so you want to restrict "find" to not search in sub-directories (find parameter "-maxdepth 1");

• restrict find results to files, because if you have directory with name "something.pdf", you may not like results (find parameter "-type f");

• cp second parameter /home/peace/Desktop/yello is a result filename? but what if pdfgrep can find "yello" in few pdf files, which one is a correct result? if "/home/peace/Desktop/yello" is a directory, you want to add "/" at the end. so I think it is a directory where we place result files.

So here we go:

find /home/peace/ -maxdepth 1 -type f -iname "*.pdf" -exec sh -c '
  for f do
    for i in yello green blue grey black white; do
      pdfgrep -iqe "$i" "$f" &&
        cp -f "$f" "/home/peace/Desktop/$i/"
    done
  done' sh {} + 

we also can add a check if result directory exists.