match at least two patterns from another file

Question

the basic code to seach a match for one string

cat fileA | grep -Fwf include.txt

How do can we use a code to match at least two patterns from that include.list

file A 
data1 khc001 khc002 vp005
data1 fbc001 cs004 khc001

include.txt
khc001
khc002

correct output line 1: data1 khc001 khc002 vp005

in the following e.g only 2 patterns are listed, but the list contains much more this is why awk '/pattern1/ && /pattern2/' is not appropriate.

Answer 1

It would be rather easy to do this with awk, counting the number of fields on each line in fileA that are equal to the strings in the include.txt file:

awk 'NR == FNR { p[$1]; next }
     {
         c = 0
         for (i = 1; i <= NF; ++i) if ($i in p) c++
         if ( c >= 2 ) print
     }' include.txt fileA

This first reads the include.txt file and uses the words as keys in an associative array. It then reads the second file and for each row, it iterates over the fields and tests each one to see whether it matches any of the keys.

For each match, we increment a counter, and if the counter is equal or grater than two at the end, we print the line.

---

Alternative formulation of the code for people who likes "one-liners":

awk 'NR==FNR {p[$1];next} {c=0;for (i=1;i<=NF;++i) if ($i in p) c++} c>=2' include.txt fileA

Answer 2

This should work assuming the order of patterns are the same way as in inputfile but not mis-order:

grep -F " $(tr '\n' ' ' <patterns)" infile

Answer 3

I was able to accomplish this with the following grepception:

grep -Fwf <(grep -v $(grep -oFwf include.txt fileA | head -1) include.txt) fileA

This will remove one of the matching patterns from include.txt and ensure there is at least one other match.

Answer 4

Another awk

awk '
  NR==FNR {
    a[NR]=$0
    next }
  !b { b=NR }
  {
    c=$0
    for(i=1;i<b;i++)
        if(!sub("\\<"a[i]"\\>","",c))
            next
  }1
' include.txt file\ A

---

Try to remove each word from include.txt in each line.

If a word is not remove not print the line.

Answer 5

grep -Fwonf include.txt file_A | 
uniq | 
cut -d: -f1 | 
printf '%dp\n' $(uniq -d) | 
ed -s file_A 

Testing

The content of files (file_A more complicated for testing):

$ tail -n +1 -- file_A include.txt 
==> file_A <==
data1 khc001 khc002 vp005
data1 fbc001 cs004 khc001
data1 khc001 khc001 vp005
data1 khc002 khc001 vp005

==> include.txt <==
khc001
khc002

Output

data1 khc001 khc002 vp005
data1 khc002 khc001 vp005