1

I have a file with an unique column and I would like to split this column in multiple columns according to a specific string (chr)

Input looks like this:

chr10:127293562-127293909
BRUNOL4(Hs/Mm)
CPEB4(Hs/Mm)
CUG-BP(Hs/Mm)
DAZAP1(Hs/Mm)
ENOX1(Hs/Mm)
FMR1(Hs/Mm)
chr11:49214073-49214804
BRUNOL4(Hs/Mm)
BRUNOL5(Hs/Mm)
CPEB2(Hs/Mm)
CPEB4(Hs/Mm)
CUG-BP(Hs/Mm)
HNRNPC(Hs/Mm)

The output should look like this:

chr10:127293562-127293909  chr11:49214073-49214804
BRUNOL4(Hs/Mm)             BRUNOL4(Hs/Mm)
CPEB4(Hs/Mm)               BRUNOL5(Hs/Mm)    
CUG-BP(Hs/Mm)              CPEB2(Hs/Mm)
DAZAP1(Hs/Mm)              CPEB4(Hs/Mm)    
ENOX1(Hs/Mm)               CUG-BP(Hs/Mm)
FMR1(Hs/Mm)                HNRNPC(Hs/Mm)

Any idea would be really appreciate.

Improve this question

2 Answers 2

Reset to default
2 
awk '/^chr/{i++} 
           {print > "_aux" i }
       END {system( "paste _aux* | column -tn; rm _aux*")}' file
  • the first 2 lines (with print > "_aux" i), split the input into a set of files _aux1 ... _auxn (each file = a column)
  • in the end, paste _aux* | column -tn pastes and format the parts.

This solution can deal with several columns (I hope).

Improve this answer
1

It is a typical awk problem:

#!/usr/bin/awk -f
BEGIN{ col = -1; l = 0; r = 0; width = 0; }
/^chr[0-9]+:/ {
        ++col;
}
{
        if ( col == 0 ) {
                L[l++] = $0;
        } else {
                R[r++] = $0;
        }
        if ( length ($0) > width ) {
                width = length ($0) ;
        }
}
END {
        for ( i = 0; i < l; ++i ) {
                printf "%-*s %s\n", width, L[i], R[i];
        }
}

Call that script "foo" and make it executable,l and pipe your data to it:

./foo < foo.in

giving

chr10:127293562-127293909 chr11:49214073-49214804
BRUNOL4(Hs/Mm)            BRUNOL4(Hs/Mm)
CPEB4(Hs/Mm)              BRUNOL5(Hs/Mm)
CUG-BP(Hs/Mm)             CPEB2(Hs/Mm)
DAZAP1(Hs/Mm)             CPEB4(Hs/Mm)
ENOX1(Hs/Mm)              CUG-BP(Hs/Mm)
FMR1(Hs/Mm)               HNRNPC(Hs/Mm)

That assumes the left/right columns have the same number of items, and that you have only two columns. awk has only one-dimensional arrays. If your problem requires more columns (say, an arbitrary number), the solution in awk (or preferably perl) would be more complicated. For that, you would need a clearer question to resolve how to do that.

Improve this answer
3
  • indeed is more complicated, because i have several "chr" characters in the starting column and there is not a stable number of items in between the first "chr" and the second, the third etc.. Commented Sep 21, 2016 at 9:23
  • Then you need to ask new questions to resolve those points :-) Commented Sep 21, 2016 at 9:25
  • cool! +1, good printf formating option! Commented Sep 21, 2016 at 14:28

You must log in to answer this question.

Start asking to get answers

Find the answer to your question by asking.

Ask question

Explore related questions

See similar questions with these tags.