awk FS with back slashes

Question

I use the command find . -maxdepth 1 -not -type d which generates output like ./filename.1.out

I pipe the find command output to awk. The goal is to split on either the literal ./ or .. I have it working using:

find . -maxdepth 1 -not -type d | gawk 'BEGIN { FS = "(\\./)|(\\.)" } ; { print NF }'

In fact it works if I drop the first backslash in the first set of paren. Ex:

find . -maxdepth 1 -not -type d | gawk 'BEGIN { FS = "(\./)|(\\.)" } ; { print NF }'

What I don't understand - and my question is why does it not work if I use:

find . -maxdepth 1 -not -type d | gawk 'BEGIN { FS = "(\./)|(\.)" } ; { print NF }'

By "not work" I mean NF returns with a number as if the second paren was a regex . character (to match any type of character). Maybe I'm answering my own question... but as I look at the commands/behavior it would appear that the initial backslash is being ignored. In fact, there was a warning escape sequence message saying that \. was being treated as plain '.'. But I didn't really understand what it was doing until I began printing NF.

And indeed... the awk doc for escape sequences (https://www.gnu.org/software/gawk/manual/html_node/Escape-Sequences.html#Escape-Sequences) say:

The backslash character itself is another character that cannot be included normally; you must write \\ to put one backslash in the string or regexp.

So if I wanted to wring a regex to match a dollar sign then I would need FS="\\$"?

The post was originally to ask why it was happening. Then I believe I may have pieced things together. If I am wrong then please set me straight.

Answer 1

The FS value was scanned twice, the first as a string value and the second as an ERE (See Lexical Conventions).

And also, POSIX did not specify the behavior of \c when c is not one of ", /, \ddd with d is one of octal digits, \, a, b, f, n, r, t, v. So you don't know whether string \c will be passed as \c or c to ERE.

gawk, nawk, and Brian Kernighan's own version give you c, while mawk give you \c:

$ for AWK in gawk mawk nawk bk-awk; do
  printf '<%s>\n' "$AWK"
  echo | "$AWK" -F '\.' '{print FS}'
done
<gawk>
gawk: warning: escape sequence `\.' treated as plain `.'
.
<mawk>
\.
<nawk>
.
<bk-awk>
.

Because \\ will always be recognized as \, then you will be safe with \\c:

$ for AWK in gawk mawk nawk bk-awk; do
printf '<%s>\n' "$AWK"; echo | "$AWK" -F '\\.' '{print FS}'
done
<gawk>
\.
<mawk>
\.
<nawk>
\.
<bk-awk>
\.

The string value of \\c will be \c, so using it as an ERE give you the desired result.

Answer 2

\x becomes one character in a double-quoted string (just like in most shells and C) before it's regarded as a regex, so you do need to type \\. to construct \..

Let's test that (you don't need the parentheses since the alternation operator | has the lowest precedence):

$ echo ./a.b.c | gawk 'BEGIN { FS = "\.|\./" } { for (i=1; i<=NF; i++) { print i ": " $i } }'
gawk: cmd. line:1: warning: escape sequence `\.' treated as plain `.'
1: 
2: 
3: 
4: 
5: 
6: 
7: 

The warning is telling you that the escape sequence in the string is superfluous. So FS is .|./ and you're splitting on every character, yielding a bunch of empty fields.

Now with the doubled-up \:

$ echo ./a.b.c | gawk 'BEGIN { FS = "\\.|\\./" } { for (i=1; i<=NF; i++) { print i ": " $i } }'
1: 
2: a
3: b
4: c