Executing a 'perl command' from shell and executing the same command from perl script using system command

Question

I am not able to take care of special characters.

I have the following perl script.

while(@mapping_array[$i])
{  
  chomp(@mapping_array[$i]);
  my @core= split ( /  / , $mapping_array[$i]) ;
  @core[0] =~ tr/ //ds ;   ## Deleting blank spaces
  @core[1] =~ tr/ //ds ;     
  system("perl -pi -e 's/@core[0]/@core[1]/' $testproc ");  
  print "@core[0] \n";
  print "@core[1] \n";
  $i++;
}

The issue is that my @core[0] variable could be a simple string like abc or a more complex one like TEST[1]. My script works as expected for abc, replacing it with the value of @core[1], but it failes if my @core[0] is TEST[1].

Using ? instead of / in the substitution operator doesn't help. How can I do this correctly?

Answer 1

Sounds like you're looking for quotemeta. As explained in perldoc -f quotemeta:

quotemeta EXPR
        Returns the value of EXPR with all the ASCII non-"word" characters
        backslashed. (That is, all ASCII characters not matching
        "/[A-Za-z_0-9]/" will be preceded by a backslash in the returned
        string, regardless of any locale settings.) This is the internal
        function implementing the "\Q" escape in double-quoted strings.

So, your script would be (note that array elements should be specified as $foo[N], not @foo[N]):

chomp(@mapping_array);
while($mapping_array[$i])
{  
    my @core= split ( /  / , $mapping_array[$i]) ;
    $core[0] =~ tr/ //ds ;   ## // Deleting blank spaces
    $core[1] =~ tr/ //ds ;   # / fix SO highlighting
    my($k,$l)=(quotemeta($core[0]),quotemeta($core[1]))
    system("perl -pi -e 's/$k/$l/' $testproc "); 
    print "$core[0] \n$core[1] \n";
    $i++;
}

Answer 2

Running Perl from Perl can usually be avoided.

for my $both (@mapping) {
    my ($regex, $replace) = split /  /, $both;
    tr/ //ds for $regex, $replace;                                                                   # // Fix SO highlighting bug.

    open my $IN,  '<', $testproc or die $!;
    open my $OUT, '>', "$testproc.new" or die $!;
    while (<$IN>) {
        s/\Q$regex/$replace/;
        print {$OUT} $_;
    }
    close $OUT or die $!;
    rename $testproc, "$testproc.old" or die $!;
    rename "$testproc.new", $testproc or die $!;
}

The \Q corresponds to quotemeta which prevents interpretation of special characters in the $regex variable.

Answer 3

First off - turn on strict and warnings at the top of your program:

use strict;
use warnings;

This will help you identify errors like @core[0] isn't actually right.

However the second problem is - you're sending meta characters to your regex - [] means something special in regex.

So what you really need is the quotemeta function.

print quotemeta '@core[0]';

Which turns it into:

\@core\[0\]

Or

print quotemeta $core[0]; 

Which in the example you give will print:

TEST\[1\]

Of course, you also probably don't need to system() call perl from within perl. That's just inefficient and messy.

Answer 4

Use \Q in the regexp to remove special meaning from chars:

system("perl -pi -e 's/\\Q$core[0]/$core[1]/' $testproc ");