awk print conditions

Question

Trying to print lines with a condition, example -

input example

Hello:world
Hello:worlds:
Hello:world:example

attempt -

awk -F":" print $1 " + " $2 && if($3 != "") { " + " $3 }

so expected output would be

Hello + world
Hello + worlds
Hello + world + example

Is it only the 3rd field that could possibly be empty, or do you want to delete all empty fields? — Kusalananda
– Kusalananda ♦, Commented Aug 31, 2019 at 17:55
You have other issues with your code but the big, glaring one is: tools that interpret scripts (awk, sed perl, rub, etc.) require you to provide the scribt within quotes (single or double) or in a file or some other clearly delimited way. You can't just write awk script, you have to write awk 'script' or awk -f scriptfile. — Ed Morton
– Ed Morton, Commented Sep 1, 2019 at 12:55

Kusalananda · Accepted Answer · 2019-09-01 16:07:41Z

If you only have to care about an empty last field, then using sed would be shorter:

$ sed 's/:$//; s/:/ + /g' file
Hello + world
Hello + worlds
Hello + world + example

Your attempted awk command can be salvaged like this:

$ awk -F":" '{ print $1 " + " $2 ($3 != "" ? " + " $3 : "") }' file
Hello + world
Hello + worlds
Hello + world + example

Or, by using OFS (the output field delimiter):

$ awk -F":" -v OFS=' + ' '{ print $1, $2 ($3 != "" ? OFS $3 : "") }' file
Hello + world
Hello + worlds
Hello + world + example

Additionally getting rid of the negative test:

$ awk -F":" -v OFS=' + ' '{ print $1, $2 ($3 == "" ? "" : OFS $3 ) }' file
Hello + world
Hello + worlds
Hello + world + example

Cyrus · Accepted Answer · 2019-09-02 01:12:35Z

5

If last column is empty, remove last column from output. $1=$1 forces awk to recreate the row with the output field separator (OFS).

awk '$NF=="" {NF--} {$1=$1}1' FS=':' OFS=' + ' file

Output:

Hello + world
Hello + worlds
Hello + world + example

answered Aug 31, 2019 at 17:59

Cyrus

12.8k3 gold badges32 silver badges55 bronze badges

2 Answers 2