Why awk 'NR%2 == 1?ORS=";":ORS="\n"' give syntax error?

Unparenthesized ternary expressions cause syntax errors in various awk versions in various contexts, not just the context and awk version already mentioned. Heres another example on MacOS:

$ awk --version
awk version 20070501

$ awk 'BEGIN{print 1 == 2 ? 3 : 4}'
awk: syntax error at source line 1
 context is
    {print 1 >>>  == <<<
awk: illegal statement at source line 1
awk: illegal statement at source line 1

$ awk 'BEGIN{print (1 == 2 ? 3 : 4)}'
4

$ awk 'BEGIN{print (1 == 2) ? 3 : 4}'
4

Of the 2 that work, I find print (1 == 2 ? 3 : 4) the more readable, especially when you get nested ternaries:

$ awk 'BEGIN{print (1 == 2 ? (6 == 7 ? 8 : 3) : 4)}'
4

$ awk 'BEGIN{print (1 == 2) ? (6 == 7) ? 8 : 3 : 4}'
4

so that's what I always use and the additionally add parens around just the conditions if/when useful, usually for readability.

Since parenthesized ternaries are always easier to read than unparenthesized, there's simply no good reason to ever write one without parentheses.

You should also never use an assignment in a conditional context unless you need the result of the assignment to be evaluated as a condition, which you don't.

What you're trying to do should be written as:

$ awk '{ORS=(NR%2 ? ";" : RS)} 1' file
A 25 27 50;B 35 37 75
C 75 78 80;D 99 88 76

Rewritten to avoid the awkward quoted strings, your construct is like this:

1 > 0 ? a = 1 : a = 2

It's not exactly ambiguous, since it can only be usefully parsed like (1 > 0) ? (a = 1) : (a = 2). But according to POSIX, the assignment has lower priority than the conditional operator ?:, so Busybox may be trying to parse it like (1 > 0 ? a) = (1 : a) = (2), which doesn't really work.

It also doesn't work in C (Debian's gcc 6.3.0-18+deb9u1), so I wouldn't say Busybox is entirely wrong here:

/tmp$ cat ternary.c
int main(void)
{
    int a;
    1 > 0 ? a = 11 : a = 22;
}
/tmp$ gcc -Wall -o ternary ternary.c 
ternary.c: In function ‘main’:
ternary.c:4:24: error: lvalue required as left operand of assignment
     1 > 0 ? a = 11 : a = 22;
                        ^

(I suppose the language lawyers at stackoverflow could tell exactly why and how that should or should not work.)

You could add the parenthesis around the assignments, but that should be written as a = 1 > 0 ? 11 : 22. This is the reason assignment does have lower precedence than ?:, if it didn't, that would parse as (a = (1 > 0)) ? 11 : 22 which usually isn't what you want.

On the other hand, if you were to want the target of the assignment to change based on the condition, you really should use a full if sentence for clarity instead of 1 > 0 ? (a = 11) : (b = 22).

perhaps :

echo "${cccccccc}"
echo
echo "${cccccccc}" \
\
| mawk -F. 'ORS=substr(";\n",_-(NR%_--),NF=_++)' \_=2 OFS= | ecp

A 25 27 50
B 35 37 75
C 75 78 80
D 99 88 76.

 
A 25 27 50;B 35 37 75
C 75 78 80;D 99 88 76

or even simpler - a solution that uses leverages lots of built-in variables to do the heavy lifting :

mawk -F. 'NF=sub(FS,(NR % _)?":" :"\n",ORS)' OFS='' \_=2

If you prefer a getline approach, then you don't even have to spend effort on calculating NR % 2 :

 echo;  echo "${cccccccc}"
 echo;  echo "${cccccccc}" \
 \
 | mawk -F. '$!_=$-_=sprintf("%s;%s",$( NF ^= !NF ),
                                     $!(NF  = getline))' OFS=''

A 25 27 50
B 35 37 75
C 75 78 80
D 99 88 76.

 
A 25 27 50;B 35 37 75
C 75 78 80;D 99 88 76

If you're into really exotic syntax, perhaps even

mawk -F. 'sub("^",($!(NF = !_))";",$!(NF = getline))' OFS=


A 25 27 50
B 35 37 75
C 75 78 80
D 99 88 76.

 
A 25 27 50;B 35 37 75
C 75 78 80;D 99 88 76