Use Sed to replace a string with another string obtained from a regex

Question

I want to replace a string (in the example the word Linux) with whatever is between the #'s on the first line.

So I want to turn:

#Windows#
1. Linux Sysadmin, Linux Scripting etc.
2. Databases - Oracle, mySQL etc.
3. Security (Firewall, Network, Online Security etc)
4. Storage in Linux
5. Productivity (Too many technologies to explore, not much time available)

into:

1. Windows Sysadmin, Windows Scripting etc.
2. Databases - Oracle, mySQL etc.
3. Security (Firewall, Network, Online Security etc)
4. Storage in Windows
5. Productivity (Too many technologies to explore, not much time available)

or

#Solaris#
1. Linux Sysadmin, Linux Scripting etc.
2. Databases - Oracle, mySQL etc.
3. Security (Firewall, Network, Online Security etc)
4. Storage in Linux
5. Productivity (Too many technologies to explore, not much time available)

into:

1. Solaris Sysadmin, Solaris Scripting etc.
2. Databases - Oracle, mySQL etc.
3. Security (Firewall, Network, Online Security etc)
4. Storage in Solaris
5. Productivity (Too many technologies to explore, not much time available)

Just using sed. I've got as far as: sed ' /^#[a-zA-Z ]*/{ h d } /Linux/ G'

I think what I need to do is is run a regular expression using the hold buffer as the replacement pattern which I guess would look like s/Linux/g but I can't find a way to do this. Anyone got any ideas?

anubhava · Accepted Answer · 2012-04-03 16:57:21Z

3

You will be better off using awk. Consider this script:

awk '/^#/ {gsub("#", "", $0); txt=$0} {gsub("Linux", txt, $0); print}' file.txt

answered Apr 3, 2012 at 16:57

anubhava

790k67 gold badges603 silver badges671 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Andrew Hancox Over a year ago

I want to do this in the context of an apache mod_sed directive, there's no performant way that I'm aware of to run apache output through awk.

Andrew Clark · Accepted Answer · 2012-04-03 23:30:43Z

Here is an sed solution:

sed '
/^#.*#$/{                      # if replacement text is matchd
s/#//g                           # remove all pound chars
h                                # copy pattern space to hold space
d                                # delete pattern space and start over
}                              # end if
:a                             # create label "a"
G                              # append hold to pattern
s/Linux\(.*\)\n\(.*\)/\2\1/    # replace Linux with contents of hold space
ta                             # if above replacement succeeded, go to "a"
s/\n.*//                       # remove replacement text and print pattern space
' file.txt

One-liner if you can use ; to separate commands:

sed '/^#.*#$/{s/#//g;h;d};:a;G;s/Linux\(.*\)\n\(.*\)/\2\1/;ta;s/\n.*//' file.txt

Interesting, I had thought that without the -n switch it was resulting in an extra newline at the beginning of the output, but I just tested it again the output looked correct. Just edited my answer to remove it.

Collectives™ on Stack Overflow

Use Sed to replace a string with another string obtained from a regex

2 Answers 2

1 Comment

1 Comment

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

1 Comment

Related