Batch file FOR loop improvements

Question

We've got code in productions, that checks file attributes (result of check.bat file1.bin returns 0 or 1) and restart user processes if necessary (if returned 1, then restart process). Code is working fine, but I just wanted to ask is there a way to improve it with FOR loop, since we really do the same thing every cycle, but with +1 to username, task name and filename

@echo off

:cycle1
FOR /F "tokens=* USEBACKQ" %%F IN (`check.bat file1.bin`) DO (SET var=%%F )
if %var% == 1 (taskkill /f /fi "USERNAME eq user1" & SCHTASKS /RUN /TN "task1")
goto cycle2

:cycle2
FOR /F "tokens=* USEBACKQ" %%F IN (`check.bat file2.bin`) DO (SET var=%%F )
if %var% == 1 (taskkill /f /fi "USERNAME eq user2" & SCHTASKS /RUN /TN "task2") 
goto cycle3

:cycle3
FOR /F "tokens=* USEBACKQ" %%F IN (`check.bat file3.bin`) DO (SET var=%%F )
if %var% == 1 (taskkill /f /fi "USERNAME eq user3" & SCHTASKS /RUN /TN "task3") 
goto eof

:eof
exit /b 0

Do you want to increment the numbers indefinitely, or just loop through the numbers 1 through 3? — SomethingDark
– SomethingDark, Commented Dec 18, 2021 at 5:26

score 1 · Accepted Answer · 2021-12-18 06:14:32Z

You can use a for /l loop to increment file numbers. I also made some other small changes to make the code simpler, no need for those code blocks:

@echo off
for /l %%a in (1,1,3) do for /F "delims=" %%F IN ('check.bat "file%%a.bin"') do (
    if %%F equ 1 taskkill /f /fi "USERNAME eq user%%a" & SCHTASKS /RUN /TN "task%%a"
)

However, I am sure your users and tasks are not called user1,2,3 and task,1,2,3 so you need to define your user and task variables and still use the number increments to select each use according to the bin file number:

@echo off & setlocal enabledelayedexpansion
set "u1=Steven"
set "u2=Maddy"
set "u3=Dan"
set "t1=taskname1"
set "t2=taskname2"
set "t3=taskname3"
for /l %%a in (1,1,3) do for /F "delims=" %%F IN ('check.bat "file%%a.bin"') do (
    if %%F equ 1 taskkill /f /fi "USERNAME eq !u%%a!" & SCHTASKS /RUN /TN "!t%%a!"
)

yet I has not tested the code but it seems to me to be a solution. thank you, @Gerhard!

Collectives™ on Stack Overflow

Batch file FOR loop improvements

1 Answer 1

1 Comment

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

1 Comment

Related