Find Non-Matching Strings using Application.Match in two arrays in Excel VBA

Don't use VBA'a Filter if you want a 1:1 match; Filter acts like a wildcard search so positive returns would be found for 123 in qw123op and df123uy.

Using the worksheet's Match function quickly locates 1:1 matches but are not case sensitive.

Sub findMissing()

    Dim i As Long, j As Long
    Dim data As Variant, absentArray As Variant, missingData As Variant
    Dim dict as object, k as variant

    Set dict = CreateObject("scripting.dictionary")
    dict.CompareMode = vbTextCompare

    data = Array("AB", "BC", "CD", "DE", "EF", "FG", "GH")
    absentArray = Array("AB", "BC", "DE", "GH")
    ReDim missingData(LBound(data) To UBound(data))

    j = LBound(data)
    For i = LBound(data) To UBound(data)
        If IsError(Application.Match(data(i), absentArray, 0)) Then
            'method one with array
            missingData(j) = data(i)
            j = j + 1
            'method two with dictionary
            dict.Item(data(i)) = vbNullString
        End If
    Next i
    ReDim Preserve missingData(j - 1)

    For i = LBound(missingData) To UBound(missingData)
        Debug.Print missingData(i)
    Next i

    For Each k in dict.Keys
        Debug.Print k
    Next k

End Sub