Logging in Batch with Variables

Question

The problem here is to create new log if one doesn't exist, or append to one if it does (providing it isn't too large) The problem is compounded by the use of nested variables beginning with %USERNAME% then %LOGFILE% then APPENDORNEW, trying to form APPENDORNEW into a command.

REM Set way back at the beginning of the code several sub labels back
setlocal DisableDelayedExpansion
.
.
.

Set LOGFILE=C:\Users\%USERNAME%\Documents\Logs\X.log

REM Does the logfile exist already?
REM Adjust redirection operators to create new log or appends to old log.
REM Quotes make no difference
If exist !%LOGFILE%! (set "_APPENDORNEW=^>^>"
) else (set "_APPENDORNEW=^>")

@echo on
REM This displays nothing (as expected?)
echo %_APPENDORNEW%
set /p APPENDORNEW=!%_APPENDORNEW%%LOGFILE%!

REM The display is just '\Users\%USERNAME%\Documents\Logs\X.log'
REM with the username value- but what happened to the 'C:'?

echo %APPENDORNEW%

%APPENDORNEW%: (

REM This is the command that is supposed to go >LOGFILE or >>LOGFILE
REM The cursor "hangs" here before enter resumes execution
REM The colon was suggested somewhere else- but doesn't factor here

echo Start time is: %date% %TIME%
REM Do Commands
REM This bracket is grouped within sub labels.
)

MC ND · Accepted Answer · 2014-11-25 10:59:44Z

4

>> to append to a file will also create the file if it does not exist. There is no need for the check

@echo off
    setlocal enableextensions disabledelayedexpansion

    set "logFile=test.log"
    for %%a in ("%logFile%") do if %%~za gtr 1000 (
        echo recycle log file
        type nul > "%logFile%"
    )

    set "operator=>>"
    set "log=%operator% "%logFile%""

    for /l %%a in (1 1 10) do (
        %log% echo test %%a 
    )

    %log% (
        for /l %%a in (1 1 10) do echo test2 %%a
    )

Why not assign the operator in the file size check? If a > is assigned, the second for loop, that is using the same operator, will overwrite the output from the first for loop. To avoid having to redefine the operator, it is easier to use >>

edited Nov 25, 2014 at 10:59

answered Nov 25, 2014 at 10:40

MC ND

71.1k8 gold badges95 silver badges136 bronze badges

Sign up to request clarification or add additional context in comments.

4 Comments

Laurie Stearn Over a year ago

I thought as much, yet with this "dysfunctional" code it wasn't happening. Used in above way with brackets there seemed to be a difference. Also the caveat on size of the logfile.

MC ND Over a year ago

@LaurieStearn, It seems you have problems with your quotes. Test the code in the answer.

Laurie Stearn Over a year ago

That works fine. Thanks. How does one wrap that in to a code section to be logged. Just insert after your code: >>%logfile% (codng) ?

MC ND Over a year ago

@LaurieStearn, answer updated, see the second for loop

Collectives™ on Stack Overflow

Logging in Batch with Variables

1 Answer 1

4 Comments

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

4 Comments

Related