2

Given the following dumper output is there a way to iterate through each hash to list only the items under each results->id record? I want to be able to say things like:

print $results{1342}{'domain'};

and have the statement return testing11.com as a result.

Would I have to first read through all of results array and then use $results[$counter]{id} to access the data in there ? I'm not sure how to proceed.

$VAR1 = { 
          'end_time' => 1466017739,
          'options' => {
                         'hour_offset' => '00',
                         'timezone' => 'America/New_York'
                       },
          'field_headers' => {
                              'priority' => 'Priority',
                              'status' => 'Status',
                              'assignee_external_id' => 'Assignee external id',
                              'initially_assigned_at' => 'Initially assigned at'
                             },
          'results' => [
                         {
                           'priority' => 'High',
                           'status' => 'Open',
                           'domain' => 'testing11.com',
                           'generated_timestamp' => 1546547669,
                           'id' => 1342
                          },
                         {
                           'priority' => 'Low',
                           'status' => 'Open',
                           'domain' => 'testing22.com',
                           'generated_timestamp' => 1464567669,
                           'id' => 7062
                          },
                         {
                           'priority' => 'Low',
                           'status' => 'Closed',
                           'domain' => 'testing33.com',
                           'generated_timestamp' => 1464267669,
                           'id' => 432
                          }]
      }
Improve this question
0

3 Answers 3

Reset to default
5

Your dump shows a hashref containing a scalar, two hashrefs, and an arrayref. The arrayref has hashrefs for elements. If you want to retrieve specific elements from it, you need to know the index.

$top_level->{results}->[0]->{domain};  # is 'testing11.com'
$top_level->{results}->[0]->{status};  # is 'open'

To iterate through it dereference the array

foreach my $result (@{ $top_level->{results} }) {
    print "$result->{id}\n";
}

Or you can just get values from all results elements for a particular key, say for id

my @ids = map { $_->{id} } @{ $top_level->{results} };
say "@ids";

Prints

1342 7062 432

Note that with nested structures, which contain references, you can also use syntax

$top_level->{results}[0]{domain};  # is 'testing11.com'

The -> is optional between subscripts, see rule 3. in Using References in perlref.

When the hash keys are strings they should be quoted

$top_level->{'results'}[0]{'domain'};

However, a syntax shortcut allows us to omit quotes on barewords. But if there is anything other than a bareword inside {} it will be interpreted as an expression and evaluated. So if in any doubt use quotes. You want consistent notation throughout.

Resources: Tutorial perlreftut, reference perlref and data structures cookbook, perldsc.

A direct solution is given in stevieb's answer, creating a reverse lookup. Copied here for reference

my $results = $VAR1->{results};

my %by_ip = map {$_->{id} => $_} @$results;

print "$by_ip{1342}->{domain}\n";
Improve this answer
Sign up to request clarification or add additional context in comments.

7 Comments

@Douglas A little unsure whether you had a more specific need, please let me know if so.
you've done a great job with many methods. you should throw in my hash example into the mix, as that's specifically what the OP was looking for :)
@stevieb Thank you for kind words. I'd rather throw in a note to direct them to your answer, which is I now think is exactly what they asked for. On the other hand, it may be superfluous -- there are the answers, and hopefully they have things covered now.
my understanding of this site is to provide the best answer possible, and imho, SO is useful for that when I need to search, so don't be shy about taking from my answer, especially when I told you to :P that said, I'm sure it's frowned upon to 'steal' from others answers without at least stating you've done so, but that's clearly not the case here
you covered many angles, so if you want to add more to your answer from what I posted, I'm down with that. The community will decide which answer is more effective anyhow. For discussions, I belong to perlmonks. For directed information only, I'm here
|
2

You need to transform the inner $results array into a new hash:

my $results = $VAR1->{results};

my %modded = map {$_->{id} => $_} @$results;

print "$modded{1342}->{domain}\n";

Output:

testing11.com

What that does is for each hash reference inside @$results, takes the value of the id key, sets it as a new key inside of a new hash (%modded), and then assigns the whole hash ref we're working with to the value of that numbered key.

Improve this answer

5 Comments

Ah, right, this may well have been what the OP is about. It crossed my mind that it may need a new data structure but then I decided the other way.
yeah. I've done this a few ways in the past, this one seemed to work best for this type of struct
Yes, that's a nice way to turn it around. What I meant is that I decided to go for more of an overall explanation over a reverse look up. Good reading of the question :). Perhaps ... call it %by_id or some such?
Btw, the timing of these comments has been a little funny for me in the past hour or so ... I see them quite a bit later than what the timestamp shows. Dunno why
yeah. I've had some ``glitches'' with comments :) it's all my fault. %by_id is probably a much better name.
1

For completeness, TIMTOWTDI-ness and -Ofun if you use the latest perl (use v5.24;), with postfix dereferencing (enabled by default), and experimental support for reference aliasing (use feature 'refalias';) then you can dereference $VAR1 and assign it to an alias (%data) which you can then access as a regular hash:

use v5.24 ;
use feature 'refaliasing';

my $VAR1 = [AS ABOVE] ;
foreach \my %data ( $VAR1->{results}->@* ) { say $data{domain} };

I like this usage (though at this point it is far from an accepted "idiom") because you invoke the dereferencing syntax "once" - either the postfix or traditional form - and then get a data structure where it is not necessary to use -> inside the block .

Of course you can do this by copying into a temporary hash. but aliasing can be seen as "more efficient and readable" (cf. Data::Alias).

Further References:

Improve this answer

Comments

Start asking to get answers

Find the answer to your question by asking.

Ask question

Explore related questions

See similar questions with these tags.