Why is the following batch code not working when put in IF-statement?

Question

So i have this code to output the filesize of a file, then replace the file and check the size again:

FOR %%A IN (%userprofile%\remove.me) DO (
    set size=%%~zA
)
pause
echo  before:%size%
copy %userprofile%\copy.me %userprofile%\remove.me
pause
FOR %%B IN (%userprofile%\remove.me) DO (
    set size2=%%~zB
)
pause
echo after:%size2%
pause
exit

It works perfectly fine, but when i try to check if the remove.me file exists before executing the code it wont output the filesizes:

if EXIST %userprofile%\remove.me (
FOR %%A IN (%userprofile%\remove.me) DO (
    set size=%%~zA
)
pause
echo  before:%size%
copy %userprofile%\copy.me %userprofile%\remove.me
pause
FOR %%B IN (%userprofile%\remove.me) DO (
    set size2=%%~zB
)
pause
echo after:%size2%
pause
exit
)

It will just say

before:

after:

without the filesizes. If i try to escape the brackets inside the code that gets run by the if-statement it will just return that (C:\Users\Myaccountname\remove.me) does not follow the syntax.

I can't figure out why this is happening and how to fix this. Don't judge me, im new to batch .-.

try with if EXIST "%userprofile%\remove.me" and FOR %%A IN ("%userprofile%\remove.me") — npocmaka
– npocmaka, Commented Dec 17, 2017 at 13:12
@npocmaka added a setlocal ENABLEDELAYEDEXPANSION at the start of the script, nothing changed. — leumasme
– leumasme, Commented Dec 17, 2017 at 13:28

npocmaka · Accepted Answer · 2017-12-17 13:36:08Z

1

You are changing and accessing value inside brackets context.So you need delayed expansion

setlocal enableDelayedExpansion
if EXIST "%userprofile%\remove.me" (
    FOR %%A IN ("%userprofile%\remove.me") DO (
        set size=%%~zA
    )
    pause
    echo  before:!size!
    copy "%userprofile%\copy.me" "%userprofile%\remove.me"
    pause
    FOR %%B IN ("%userprofile%\remove.me") DO (
        set size2=%%~zB
    )
    pause
    echo after:!size2!
    pause
    exit

)

edited Dec 17, 2017 at 13:36

answered Dec 17, 2017 at 13:28

npocmaka

57.8k19 gold badges162 silver badges199 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

leumasme Over a year ago

with this code the batch console instantly closes after running "setlocal enableDelayedExpansion" :/

npocmaka Over a year ago

@Temm - check it now. By accidend I've left the last closing bracket outside of the code block.

Collectives™ on Stack Overflow

Why is the following batch code not working when put in IF-statement?

1 Answer 1

2 Comments

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

2 Comments

Related